nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

insight set object attribute value of type user by username

Chris_v50hrr

we have object type "user" with attribute "name" and attribute "user jira" (type user)

we would like to assign attribute "user jira" automatically based on mapping "user"."name" = username of "user jira"

manual assignement works but we would like to automate it.

can someone help me please. thank you.

Accepted answers

PD Sheehan

Can you provide a bit more context around this operation?

Are your user objects populated automatically with some import?
Or are you looking to create user objects manually by providing the username in the user.name attribute and have the "user jira" attribute automatically populated after saving so that object creators don't have to enter the same value twice?

All comments

PD Sheehan

Can you provide a bit more context around this operation?

Chris_v50hrr

yes, your second assumption is correct. populated on save and for existing objects. we have a a lot of user objects which must be connected to jira users (jira users are imported via ldap).

(further step could be create user objects also via ldap import)

thank you.

PD Sheehan

If you have your user object type connected to LDAP Import, you could just map the ldap attribute that contains your username to both the "name" and the "user jira" insight attribute and all the existing objects will be refreshed with the jira account.

You don't need to use automation for it.

To have 1 field populated on the basis of another one on the create or update event requires a groovy script.

Here is something I cobbled together from other existing scripts I have:

import com.atlassian.jira.component.ComponentAccessor
import com.riadalabs.jira.plugins.insight.channel.external.api.facade.ObjectFacade
import com.riadalabs.jira.plugins.insight.channel.external.api.facade.ObjectTypeFacade
import com.riadalabs.jira.plugins.insight.channel.external.api.facade.ObjectTypeAttributeFacade
import com.riadalabs.jira.plugins.insight.services.model.ObjectBean
import com.riadalabs.jira.plugins.insight.services.model.ObjectAttributeBean
import com.riadalabs.jira.plugins.insight.services.events.EventDispatchOption

def objectFacade = ComponentAccessor.getOSGiComponentInstanceOfType(ObjectFacade)
def objectTypeFacade = ComponentAccessor.getOSGiComponentInstanceOfType(ObjectTypeFacade)
def objectTypeAttributeFacade = ComponentAccessor.getOSGiComponentInstanceOfType(ObjectTypeAttributeFacade)

def ATTRIBUTE_NAME_NAME = 'Username'
def ATTRIBUTE_NAME_JIRA = 'Jira Account'

def objectType = objectTypeFacade.loadObjectType(object.objectTypeId)

doNameRefresh = true
if (this.binding.variables.containsKey('objectUpdateList')) {
    doDateRefresh = this.binding.variable['objectUpdateList'].any {
        it.attributeName in [ATTRIBUTE_NAME_NAME, ATTRIBUTE_NAME_JIRA]
}
}

if (doNameRefresh) {
def nameAttributeBean = objectTypeAttributeFacade.findObjectTypeAttributeBeans(objectType.id).find {
        it.name == ATTRIBUTE_NAME_NAME
}
    if (!nameAttributeBean) {
        log.error "Unable to find attribute with name: $ATTRIBUTE_NAME_NAME"
        return
    }
def jiraUserAttributeBean = objectTypeAttributeFacade.findObjectTypeAttributeBeans(objectType.id).find {
        it.name == ATTRIBUTE_NAME_JIRA
}
    if (!jiraUserAttributeBean) {
        log.error "Unable to find attribute with name: $ATTRIBUTE_NAME_JIRA"
        return
    }
def name = object.getObjectAttributeBeans().find {
        ObjectAttributeBean it -> it.objectTypeAttributeId == nameAttributeBean.id
    }.getObjectAttributeValueBeans()[0].value
def jiraAttrVals = object.getObjectAttributeBeans().find {
        ObjectAttributeBean it -> it.objectTypeAttributeId == jiraUserAttributeBean.id
    }?.getObjectAttributeValueBeans()
def jiraAttrVal = jiraAttrVals ? jiraAttrVals[0].value : null
    def jiraUser = ComponentAccessor.userManager.getUserByName(name as String)
if (!jiraUser) {
        log.error "Unable to find jira user with name $name"
        return
    }
if (jiraAttrVal != jiraUser.key) {
def newJiraAttr = object.createObjectAttributeBean(jiraUserAttributeBean)
def newJiraAttrVal = newJiraAttr.createObjectAttributeValueBean()
        newJiraAttrVal.setValue(jiraUserAttributeBean, jiraUser.key)
        newJiraAttr.setObjectAttributeValueBeans([newJiraAttrVal])
        objectFacade.storeObjectAttributeBean(newJiraAttr, EventDispatchOption.DO_NOT_DISPATCH)
    }
}

You just need to adjust ATTRIBUTE_NAME_NAME and ATTRIBUTE_NAME_JIRA save the script in your jira-home directory, add the script to the insight whitelist and then create an Insight automation that fires on create and update and has this script as the action.

Chris_v50hrr

Many thanks. It works.

Just two small errors in line 20. Correct is:

doNameRefresh = this.binding.variables['objectUpdateList'].any {

Welcome!

It looks like you're new here. Sign in or register to get started.

Quick Links

Find more posts tagged with

server

jira-software

jira-software-server

insight