The “Require commits to be associated with a valid Jira issue” built-in pre-hook actually works as expected.
As the name of the pre-hook suggests, the pre-hook validation is based on commits. A push is allowed even the branch name doesn’t contain issue key as long as the commits contain a valid one.
I can confirm that an empty branch without associated Jira issue key can be successfully pushed from client machine.
Having said this, if you want to validate branch name on push and UI. This library script does exactly that. So, I have modified it to validate issue type instead of status name:
import com.atlassian.applinks.api.ApplicationLinkResponseHandler
import com.atlassian.applinks.api.ApplicationLinkService
import com.atlassian.applinks.api.application.jira.JiraApplicationType
import com.atlassian.bitbucket.hook.repository.RepositoryHookResult
import com.atlassian.bitbucket.repository.MinimalRef
import com.atlassian.bitbucket.repository.RefChangeType
import com.atlassian.sal.api.component.ComponentLocator
import com.atlassian.sal.api.net.Request
import com.atlassian.sal.api.net.Response
import com.atlassian.sal.api.net.ResponseException
import groovy.json.JsonSlurper
private RepositoryHookResult rejectedResult(String message) {
RepositoryHookResult.rejected(message, message)
}
private RepositoryHookResult getIssueKeyValidationResult(String issueKey, List<String> requiredIssueTypeNames, MinimalRef branchRef) {
def applicationLinkService = ComponentLocator.getComponent(ApplicationLinkService)
def primaryJiraApplicationLink = applicationLinkService.getPrimaryApplicationLink(JiraApplicationType)
def authenticatedRequestFactory = primaryJiraApplicationLink.createImpersonatingAuthenticatedRequestFactory() ?:
primaryJiraApplicationLink.createAuthenticatedRequestFactory()
authenticatedRequestFactory.createRequest(Request.MethodType.GET, "rest/api/2/issue/$issueKey")
.addHeader('Content-Type', 'application/json')
.execute(new ApplicationLinkResponseHandler<RepositoryHookResult>() {
@Override
RepositoryHookResult credentialsRequired(Response response) throws ResponseException {
rejectedResult(
"Please authenticate with Jira: ${authenticatedRequestFactory.authorisationURI}"
)
}
@Override
RepositoryHookResult handle(Response response) throws ResponseException {
if (!response.successful) {
if (response.statusCode == 404) {
return rejectedResult(
"Branch with name: ${branchRef.displayId} matches Jira issue key: $issueKey but no issue with this key exists, branch creation cancelled."
)
}
log.warn("Jira call failed, status: ${response.statusCode}.")
return rejectedResult(
'Validation of issue key in branch name failed, please contact your system administrator.'
)
}
def issueJson = new JsonSlurper().parseText(response.responseBodyAsString) as Map<String, Object>
def issueTypeName = issueJson['fields']['issuetype']['name'] as String
if (!(issueTypeName in requiredIssueTypeNames)) {
return rejectedResult(
"Issue with key: $issueKey was found from branch name, but its issue type name: ($issueTypeName) does not match the required issue type names: ($requiredIssueTypeNames)."
)
}
RepositoryHookResult.accepted()
}
})
}
def builder = new RepositoryHookResult.Builder()
def requiredIssueTypeNames = ['Story', 'Defect']
// A regular expression for extracting Jira issue keys from branch names, this is the default regular expression used by Bitbucket.
// If your Jira issue keys do not match the default pattern, alterations will need to be made here.
def jiraIssueKeyPattern = ~'(?<=^|[a-z]\\-|[\\s\\p{Punct}&&[^\\-]])([A-Z][A-Z0-9_]*-\\d+)(?![^\\W_])'
// Find all created refs which relate to a branch creation
def createdBranchRefs = refChanges.find { it.type == RefChangeType.ADD && it.refId.startsWith('refs/heads') }*.ref
// For each created branch ref, check the branch name for an issue key, and then verify the status of that issue via a linked Jira instance.
createdBranchRefs.each { branchRef ->
def matcher = branchRef.id =~ jiraIssueKeyPattern
if (matcher.find()) {
def issueKey = matcher.group(1)
builder.add(getIssueKeyValidationResult(issueKey, requiredIssueTypeNames, branchRef))
} else {
def message = "Branch with name: ${branchRef.displayId} does not contain a reference to a Jira issue."
builder.add(rejectedResult(message))
}
}
builder.build()
Please also remember to set triggers to both “branch-create” and “push”.
You must be a registered user to add a comment. If you've already registered, sign in. Otherwise, register and sign in.