It took me the whole day, but I've finally made it works into a Script Runner Rest Endpoint with my Jira SW 8.3.2 and JSD 4.3.2.
Don't ask exactly how....
Note: My goal is a one shot move of all tickets from project A to B and delete project A, making its key available again.
+ This way I can bulk move with a mapping for "Customer Request Type" which is not possible with the "move" user interface.
If any expert see something dangerous or to be improved, please be my guest.
import com.mycorp.jira.MyCustomField
import com.atlassian.jira.bc.issue.comment.CommentService
import com.atlassian.jira.bc.project.component.ProjectComponent
import com.atlassian.jira.config.properties.JiraSystemProperties
import com.atlassian.jira.event.issue.IssueEventBundleFactory
import com.atlassian.jira.event.issue.txnaware.TxnAwareEventFactory
import com.atlassian.jira.help.HelpUrls
import com.atlassian.jira.issue.IssueFieldConstants
import com.atlassian.jira.issue.IssueManager
import com.atlassian.jira.issue.MutableIssue
import com.atlassian.jira.issue.fields.CustomField
import com.atlassian.jira.issue.security.IssueSecurityHelper
import com.atlassian.jira.project.Project
import com.atlassian.jira.project.ProjectManager
import com.atlassian.jira.web.SessionKeys
import com.atlassian.jira.web.action.issue.MoveIssueConfirm
import com.atlassian.jira.web.action.issue.MoveIssueUpdateFields
import com.atlassian.jira.web.bean.MoveIssueBean
import com.onresolve.scriptrunner.runner.rest.common.CustomEndpointDelegate
import conf.MyCustFieldByEnv
import groovy.json.JsonBuilder
import groovy.transform.BaseScript
import webwork.action.ActionContext
import webwork.dispatcher.GenericDispatcher
import javax.servlet.http.HttpServletRequest
import javax.ws.rs.core.MultivaluedMap
import javax.ws.rs.core.Response
import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.component.pico.ComponentManager
import java.lang.reflect.Method
@BaseScript CustomEndpointDelegate delegate
test(httpMethod: "GET", groups: ["jira-administrators"]) { MultivaluedMap queryParams, String body, HttpServletRequest request ->
/******************************************
* Define issue to move and target project *
* And values mapping *
*******************************************/
String targetProjectKey = "<target project key>"
String issueKey = "<issue key to move>"
Map customerRequestTypeMapping = [
'default':'sptst/ef0ee952-93ff-4886-ae98-e23b61eba08f',
'spfdl/a0ef7668-4de9-42a5-a35b-8e22b59f64e6':'sptst/ef0ee952-93ff-4886-ae98-e23b61eba08f',
'spfdl/f54a4a3f-739e-45a0-93bd-8e648a3d0524':'sptst/fc3849bd-c2f1-49e9-bb5a-7853911c47e2',
'spfdl/bf077552-6d75-4b40-b4cd-3f211fb28244':'sptst/133fbf56-719d-43d7-a78a-eece3cdd4091',
'spfdl/dfe9294a-872a-4ca6-b72b-f97278c5dec5':'sptst/1b9f32b2-c9c3-40af-a109-b757fd7d1282',
]
/*******************
* Load components *
*******************/
ComponentManager componentManager = ComponentManager.getInstance()
ProjectManager projectManager = ComponentAccessor.getProjectManager()
IssueManager issueManager = ComponentAccessor.getIssueManager()
int cfCustomerRequestTypeId = MyCustFieldByEnv.getCustomFieldId("CustomerRequestType")
CustomField cfCustomerRequestType = MyCustomField.getCustFieldObjectById(cfCustomerRequestTypeId)
def requestTypeCustomFieldType = cfCustomerRequestType.getCustomFieldType()
/********************************************
* Load issue, target project and move data *
********************************************/
Project targetProject = projectManager.getProjectObjByKey(targetProjectKey)
MutableIssue targetIssue = issueManager.getIssueObject(issueKey)
MoveIssueBean moveIssueBean = new MoveIssueBean(ComponentAccessor.getConstantsManager(), projectManager)
moveIssueBean.getFieldValuesHolder().put(IssueFieldConstants.PROJECT, targetProject.id)
moveIssueBean.getFieldValuesHolder().put(IssueFieldConstants.ISSUE_TYPE, targetIssue.issueType.id.toString())
moveIssueBean.setIssueId(targetIssue.id)
moveIssueBean.setSourceIssueKey(targetIssue.key)
moveIssueBean.setTargetStatusId(targetIssue.status.id.toString())
/*************************
* Define action context * (here is the "dirty tricks")
*************************/
GenericDispatcher gd = new GenericDispatcher("Move")
request.setAttribute("jira.webwork.generic.dispatcher",gd)
gd.prepareContext()
ActionContext.session.put(SessionKeys.MOVEISSUEBEAN, moveIssueBean)
ActionContext.setRequest(request)
/********
* MOVE *
********/
MoveIssueUpdateFields moveIssueUpdateFields = new MoveIssueUpdateFields(
ComponentAccessor.getSubTaskManager(),
ComponentAccessor.getConstantsManager(),
ComponentAccessor.getWorkflowManager(),
ComponentAccessor.getFieldManager(),
ComponentAccessor.getFieldLayoutManager(),
ComponentAccessor.getIssueFactory(),
ComponentAccessor.getFieldScreenRendererFactory(),
componentManager.getComponentInstanceOfType(CommentService.class),
componentManager.getComponentInstanceOfType(IssueSecurityHelper.class),
ComponentAccessor.getUserUtil(),
componentManager.getComponentInstanceOfType(HelpUrls.class)
)
MoveIssueConfirm moveIssueConfirm = new MoveIssueConfirm(
ComponentAccessor.getSubTaskManager(),
ComponentAccessor.getAttachmentManager(),
ComponentAccessor.getConstantsManager(),
ComponentAccessor.getWorkflowManager(),
ComponentAccessor.getFieldManager(),
ComponentAccessor.getFieldLayoutManager(),
ComponentAccessor.getIssueFactory(),
ComponentAccessor.getFieldScreenRendererFactory(),
componentManager.getComponentInstanceOfType(CommentService.class),
componentManager.getComponentInstanceOfType(IssueSecurityHelper.class),
issueManager,
ComponentAccessor.getUserUtil(),
ComponentAccessor.getIssueEventManager(),
componentManager.getComponentInstanceOfType(IssueEventBundleFactory.class),
componentManager.getComponentInstanceOfType(TxnAwareEventFactory.class),
componentManager.getComponentInstanceOfType(HelpUrls.class)
)
/****************************
* Prepare move object bean *
****************************/
JiraSystemProperties.getInstance()
moveIssueUpdateFields.setId(targetIssue.id)
Method privateUpdateFieldsDoExecute = MoveIssueUpdateFields.class.getDeclaredMethod("doExecute")
privateUpdateFieldsDoExecute.setAccessible(true)
String msg = (String) privateUpdateFieldsDoExecute.invoke(moveIssueUpdateFields)
log.error(msg)
/**************************
* Include custom updates *
**************************/
// set components
Collection<ProjectComponent> targetComponents = []
targetIssue.getComponents().each{ component ->
targetComponents.add(ComponentAccessor.getProjectComponentManager().findAllForProject(targetProject.id)?.find { it.name == component.name})
}
moveIssueBean.getUpdatedIssue().setComponent(targetComponents)
// Set Request type
String sourceCustRequestType = MyCustomField.getCustFieldValueById(cfCustomerRequestTypeId,targetIssue)
String targetCustRequestType = customerRequestTypeMapping.default
if(customerRequestTypeMapping.containsKey(sourceCustRequestType)){
targetCustRequestType = customerRequestTypeMapping[sourceCustRequestType]
}
def newRequestTypeValue = requestTypeCustomFieldType.getSingularObjectFromString(targetCustRequestType)
moveIssueBean.getUpdatedIssue().setCustomFieldValue(cfCustomerRequestType, newRequestTypeValue)
/****************
* Confirm move *
****************/
moveIssueConfirm.setId(targetIssue.id)
Method privateIssueConfirmDoExecute = MoveIssueConfirm.class.getDeclaredMethod("doExecute")
// issueManager.updateIssue(user, issueObject, eventDispatchOption, args.notify)
privateIssueConfirmDoExecute.setAccessible(true)
msg = (String) privateIssueConfirmDoExecute.invoke(moveIssueConfirm)
log.error(msg)
return Response.ok(new JsonBuilder([result: "${moveIssueBean.getSourceIssueKey()} ==> ${moveIssueBean.getUpdatedIssue()}"]).toString()).build()
}
You must be a registered user to add a comment. If you've already registered, sign in. Otherwise, register and sign in.