Updating a custom field from a script listener

Jonny Carter_3nm6du

Users frequently want to move from using a Scripted Field to using a custom field that's automatically updated. This is useful for Jira Portfolio, which, as of this writing, doesn't support calculated fields. It's also useful if you need an automatic value that can be changed via the UI. The question is, how to do it in ScriptRunner?

Jonny Carter_3nm6du

Answer: setup a Script Listener to listen for the Issue Updated event with code similar to the following (tweaked where noted)

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.event.type.EventDispatchOption
import com.atlassian.jira.issue.Issue

def issue = event.issue as Issue
def desiredValue = issue.summary + issue.description //TODO: Change this to be the actual calculation you want
def customFieldName = "My Custom Field" //TODO: Change this to match the custom field you want
def customFieldManager = ComponentAccessor.customFieldManager
def field = customFieldManager.getCustomFieldObjects(issue).find{
 it.name == customFieldName
}
def currentCustomFieldValue = issue.getCustomFieldValue(field)
if (currentCustomFieldValue == desiredValue) {
 return //Quit -- we don't want to update the field if it's already correct.
}
def issueService = ComponentAccessor.getIssueService()
def issueInputParameters = issueService.newIssueInputParameters()
issueInputParameters.addCustomFieldValue(field.id, desiredValue)
def loggedInUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser
def validationResult = issueService.validateUpdate(loggedInUser,
 issue.id,
 issueInputParameters
)
if (validationResult.isValid()) {
 def updateResult = issueService.update(loggedInUser,
 validationResult,
 EventDispatchOption.DO_NOT_DISPATCH, //This is important to avoid infinite loops
 false)
 if (!updateResult.isValid()) {
 log.error "Failed to update issue $issue.key"
 log.error updateResult.errorCollection.errorMessages
 log.warn updateResult.warningCollection.warnings
 }
} else {
 log.error "Failed to update issue $issue.key"
 log.error validationResult.errorCollection.errorMessages
 log.warn validationResult.warningCollection.warnings
}