Attachment deletion based on attachment date

Asiya Fathima_wh4mzp

I want to delete attachments only based on attachment date but the script mentioned is fetching the issues based on JQL and deleting all the attachments in the Issue. 

Do we have any way to delete attachment based on attachment date

 

import com.atlassian.jira.component.ComponentAccessor;

import com.atlassian.jira.jql.parser.JqlQueryParser;

import com.atlassian.jira.issue.search.SearchQuery;

import com.atlassian.jira.issue.search.SearchResults;

import com.atlassian.jira.issue.search.SearchProvider;

import com.atlassian.jira.web.bean.PagerFilter;

import com.atlassian.jira.issue.Issue;

import com.atlassian.jira.issue.AttachmentManager;

import org.apache.log4j.Logger

import org.apache.log4j.Level

def jqlQueryParser = ComponentAccessor.getComponent(JqlQueryParser)

def searchProvider = ComponentAccessor.getComponent(SearchProvider)

def issueManager = ComponentAccessor.getIssueManager()

def user = ComponentAccessor.getJiraAuthenticationContext().getLoggedInUser()

def jqlQuery = "project = TEST AND issue in attachedOnDate(2019-05-1)"

def query = jqlQueryParser.parseQuery(jqlQuery)

def luceneQuery = SearchQuery.create(query, user)

def results = searchProvider.search(luceneQuery, PagerFilter.getUnlimitedFilter()).getResults()*.document

.collect{ComponentAccessor.issueManager.getIssueObject(it.getField('issue_id').stringValue().toLong())}

results.each {

issue ->

def attachments = ComponentAccessor.attachmentManager.getAttachments(issue)

attachments.each {attachment ->

ComponentAccessor.attachmentManager.deleteAttachment(attachment)

}

}

Evgenii

Hi, @Asiya Fathima 

You can use this script, it makes what you want. Needed time limits can be set in fromDate / toDate strings

/*
 * @author Evgeniy Isaenkov
 * @github https://github.com/Udjin79/SRUtils
 */

package ConsoleExamples

import com.atlassian.jira.bc.issue.search.SearchService
import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.issue.Issue
import com.atlassian.jira.issue.attachment.Attachment
import com.atlassian.jira.issue.search.SearchResults
import com.atlassian.jira.jql.parser.JqlQueryParser
import com.atlassian.jira.user.ApplicationUser
import com.atlassian.jira.web.bean.PagerFilter
import com.atlassian.query.Query

JqlQueryParser jqlQueryParser = ComponentAccessor.getComponent(JqlQueryParser) as JqlQueryParser
SearchService searchService = ComponentAccessor.getComponent(SearchService)
ApplicationUser user = ComponentAccessor.getJiraAuthenticationContext().getLoggedInUser()

String jqlQuery = "project = TEST AND attachments is not EMPTY"
Date fromDate = new Date("01/01/2023")
Date toDate = new Date("01/31/2023")

Query query = jqlQueryParser.parseQuery(jqlQuery)
SearchResults search = searchService.search(user, query, PagerFilter.getUnlimitedFilter())
List<Issue> results = search.results

results.each { Issue issue ->
   List<Attachment> attachments = ComponentAccessor.attachmentManager.getAttachments(issue)
   attachments.each { Attachment attachment ->
      if (attachment.created >= fromDate.toTimestamp() && attachment.created <= toDate.toTimestamp()) {
         ComponentAccessor.attachmentManager.deleteAttachment(attachment)
      }
}
}