Script fragment to hide create-subtask for specific groups in projects

Mary Mark

Hi Atlassian Community, 

Looking to create a script fragment to hide the "Create Sub-task" button under the "More" tab in a Jira issue view. 

It works for a single project and single group but I would like to add in additional groups and projects. 

This code works:

For project ABC, I can see and create a sub-task option from the "More" menu when I am in the ABC_managing team. If I am not in the group, I will not be able to see the "create sub-task" option

import com.atlassian.jira.component.ComponentAccessor
def currentUser = ComponentAccessor.getJiraAuthenticationContext().getLoggedInUser()
def groupManager = ComponentAccessor.getGroupManager()

//When there are multiple projects
def projectKeyList = ['ABC']

!(jiraHelper.project?.key in projectKeyList) || (groupManager.isUserInGroup(currentUser,"ABC_managing team"))

 

However, as soon as I add in the following for additional groups and projects, the code no longer works.

import com.atlassian.jira.component.ComponentAccessor

def currentUser = ComponentAccessor.getJiraAuthenticationContext().getLoggedInUser()

def groupManager = ComponentAccessor.getGroupManager()

//def user = ComponentAccessor.jiraAuthenticationContext.loggedInUser

//def GROUP = ['accind_managing team']

//When there are multiple projects

def projectKeyList =  ['ABC, 'DEF']

!(jiraHelper.project?.key in projectKeyList) || (groupManager.isUserInGroup(currentUser,"ABC_managing team")) || (groupManager.isUserInGroup(currentUser,"DEF_managing team"))

Would appreciate if someone can review to let me know what I am doing wrong.

Thanks in advance. 

Mary

PD Sheehan

Possibly, the only mistake is in 

def projectKeyList = ['ABC, 'DEG']

There is a missing quote after ABC.

 

But perhaps you can write this so it's easier to read:

import com.atlassian.jira.component.ComponentAccessor

def currentUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser
def groupManager = ComponentAccessor.groupManager

def restrictedProjectList = ['ABC', 'DEF']
def allowedGroupList = ['ABC_managing team', 'DEF_managing team']

if (!restrictedProjectList.contains(jiraHelper.project?.key)) return true //for all other projects, we show the menu as usual
//if we're still running here, this is a project that should limit access to the menu by group
//if the current user is member of any of the allowedGroups, then they can see the menu, otherwise they can't
allowedGroupList.any { group -> groupManager.isUserInGroup(currentUser, group) }

But perhaps, you only want members of the ABC team to have access to the menu in the ABC project. Not the DEF project. In which case, something like this would be more appropriate:

import com.atlassian.jira.component.ComponentAccessor

def currentUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser
def groupManager = ComponentAccessor.groupManager

def restrictedProjectsMap = [
   'ABC': ['ABC_managing team', 'Perhaps another Group'],
   'DEF': ['DEF_managing team']
]

if (!restrictedProjectsMap.containsKey(jiraHelper.project?.key)) return true //for all other projects, we show the menu as usual
//if we're still running here, this is a project that should limit access to the menu by groups. Let's get that list of groups.
def allowedGroupList = restrictedProjectsMap[jiraHelper.project?.key]
//if the current user is member of any of the allowedGroups, then they can see the menu, otherwise they can't
allowedGroupList.any { group -> groupManager.isUserInGroup(currentUser, group) }