Script runner mail handler - Read Body and find the custom field values to set it in jira

Omprakash Thamsetty

Hi,

 

I am trying to modify my existing Mail Handler script to find the custom field value in Email Body and then update in Jira. Example format is here 

 

Customer Name: Omprakash Thamsetty  ( This field is text field )

Severity: 1 Critical    ( This field is single selection field)

Description: TEST: Sending this email to create jira ticket via email reader

 

So how I can read Customer Name, Severity and description information from Body using script and then create the jira ticket with that info?

 

As of now we are using issueObject.setDescription(body) to set description but now I need to have some email template body as above and then add the values to custom field. How can I achieve this using Mail Handler?

 

Thanks,

Om

Radek Dostál

Not really dealing with mail handlers, but assuming we're looking at something similar to this: https://scriptrunner.adaptavist.com/latest/jira/mail-handler.html#_change_issue_status

 

So I played around the proof of concept a little bit and got to this kind of an idea - and just to point out, I did not deal with the actual handler or anything, just the console.

import com.atlassian.jira.bc.issue.IssueService
import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.config.IssueTypeManager
import com.atlassian.jira.issue.CustomFieldManager
import com.atlassian.jira.issue.IssueInputParameters
import com.atlassian.jira.issue.context.IssueContext
import com.atlassian.jira.issue.context.IssueContextImpl
import com.atlassian.jira.issue.customfields.manager.OptionsManager
import com.atlassian.jira.issue.customfields.option.Option
import com.atlassian.jira.issue.customfields.option.Options
import com.atlassian.jira.issue.fields.CustomField
import com.atlassian.jira.issue.fields.config.FieldConfig
import com.atlassian.jira.issue.issuetype.IssueType
import com.atlassian.jira.project.Project
import com.atlassian.jira.project.ProjectManager
import com.atlassian.jira.user.ApplicationUser

final String body = """This is a test body
Severity: 1 Critical
Description: sample description
"""

String severityMatcher = "Severity: .*"
String severityMatch = body.find(severityMatcher)
String severityValue = null

if (severityMatch) {
    severityValue = severityMatch.substring(severityMatch.indexOf(' '))
}

if (severityValue != null) {
//this is just an example of proof of concept, not really a fully fledged working script
    CustomFieldManager customFieldManager = ComponentAccessor.getCustomFieldManager()
    CustomField severityField = customFieldManager.getCustomFieldObjectsByName("Severity")?.first() //careful about this if you have more than 1 field with that name
    if (severityField != null) {
        ProjectManager projectManager = ComponentAccessor.getProjectManager()
        IssueTypeManager issueTypeManager = ComponentAccessor.getComponent(IssueTypeManager)

        Project project = projectManager.getProjectByCurrentKey("ABC")
        IssueType issueType = issueTypeManager.getIssueType("Task")
if (project != null && issueType != null) {
            IssueContext issueContext = new IssueContextImpl(project, issueType)
            FieldConfig fieldConfig = severityField.getRelevantConfig(issueContext)

            OptionsManager optionsManager = ComponentAccessor.getOptionsManager()
            Options options = optionsManager.getOptions(fieldConfig)
            Option criticalOption = options.findByName(severityValue)

if (criticalOption != null) {
//Now we have the custom field and custom field value, so we can create the issue with it
                ApplicationUser mailhandleruser = ComponentAccessor.getUserManager().getUserByName("mailhandler_actor")

                IssueService issueService = ComponentAccessor.getIssueService()
                IssueInputParameters issueInputParameters = issueService.newIssueInputParameters()
                issueInputParameters.with {
                    it.setSummary("abc")
                    it.setDescription("def")
                    it.addCustomFieldValue(severityField.getId(), criticalOption.getOptionId().toString())
}

                IssueService.CreateValidationResult createValidationResult = issueService.validateCreate(mailhandleruser, issueInputParameters)
if (createValidationResult.isValid())
                    issueService.create(mailhandleruser, createValidationResult)
            }
        }
    }
}

 

The question is, you say you want to create a new issue - what is your current approach to it? I think there might be 2 ways to do so. Typically IssueInputParameters is what I use: https://library.adaptavist.com/entity/update-the-value-of-custom-fields-through-the-script-console

 

So then depending on your approach it should be possible to set the value (given that everything else works). Note that I did not fully test above snippet, it's just what I would start with. You may want to incorporate part of it into your own script.

 

Another part to improve is the severity matcher. This here looks anywhere in the body. I tried to limit it to '^$' as in start and end of line, but the groovy didn't want to work with it (tried also Pattern and Matcher java classes, no budge). It's definitely possible but just couldn't fix it quickly enough. Then of course you might want to play around the regex, what if there isn't space, is your format always the same, etc., but just a general idea for now.

 

Just to re-iterate, I don't really do mail handlers, just a quick look around and thinking process what I'd do. Could still be that there is a better approach to all of this.