Jira Scriptrunner-Script to add a custom label when a option is chosen from a single select dropdown

VR_1fw1vd

Can someone please assist with the groovy script?

I need to be able to add a custom label(say 'testing') to a JIRA issue(upon creation/when edited later) when a 'selection A' is chosen from a single select dropdown. If the user at somepoint, chooses 'Selection B' - that label 'testing' should be removed off from the jira issue. 

Thanks,

VR

PD Sheehan

I'm not sure I understand what the purpose of doing that would be.

It seems redundant to have 2 aspects of an issue mean essentially the same thing.

But if you want to add/remove data from a jira issue when the issue is either created or updated, you must use a custom scripted listener.

Your listener will listen for the Issue Created and Issue Updated events.

Here is something you can start with:

import com.atlassian.jira.issue.label.LabelManager
import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.issue.customfields.option.LazyLoadedOption
import com.atlassian.jira.issue.Issue

def labelManager = ComponentAccessor.getComponent(LabelManager)
def customFieldManager = ComponentAccessor.customFieldManager
def currentUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser

def fieldName = 'drop down'
def optionValue = 'selection A'
def labelValue = 'testing'
def sendEmailOnAdd = false
def sendEmailOnRemove = false

def issue = event.issue as Issue
def cf = customFieldManager.getCustomFieldObjectsByName(fieldName)[0] //assumes you have a single custom field with that name
def selectedOption = issue.getCustomFieldValue(cf) as LazyLoadedOption
if(selectedOption && selectedOption.value == optionValue){
   def labels = issue.labels
   //make sure the lable is not already there
   if(!labels.any{it.label == labelValue}){
      labelManager.addLabel(currentUser, issue.id, labelValue, sendEmailOnAdd)
   }
} else {
   def labels = issue.labels.findAll{it.label != labelValue} //get all the labels we want to keep
   labelManager.setLabels(currentUser, issue.id, labels as Set, sendEmailOnRemove, false)
}

You might need to test to see if the index is automatically updated or if you'll need to force a reindex of the issue after adding/removing the label.