nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

Simple scripted validator - Stuck on multi-field / custom user picker validation

Michael_qy22gs

Hello all,

We are trying to ensure that one of several specific users is selected within a User Picker (single user) customfield; and that the specific user selected is within the department selected within a previous Select List (Single Choice) customfield present to the user.

For example:

We have a Select List (Single Choice) customfield called Dept which contains all departments within our group. This field asks the submitter to select their corresponding department.

After the user selects the department they are within, a User Picker (single user) customfield named Internal Approver shows up and allows the submitter to select a single user. We only want them to select from one of the following users:
1) Bob Smith (Username = bobSm)

2) Michael M (Username = micmal)

3) Test_user (Username = TestUser1)

I've been trying to create a script that handles all of this, but I can't seem to get it to work. So far I have the following:

cfValues['Dept'] == 'Dept1' && cfValues['Internal Approver'] == 'Bob Smith' || cfValues['Internal Approver'] == 'Michael M' || cfValues['Internal Approver'] == 'Test_User'

Can someone help me here?

Thanks,

Mike

Conclusion:

TLDR for those who don't want to read the back and forth. I wanted to have a validator within my create screen which allowed me to use a Select List (Single Choice) customfield to allow only specific "approvers" per value selectable within the afore mentioned Select List (Single Choice) customfield.

The code below is what we came up with:

import com.atlassian.jira.component.ComponentAccessor
import com.opensymphony.workflow.InvalidInputException

Map<String, List<String>> departmentApproverMap = [
   Dept1: ['bobSm', 'micmal', 'TestUser1'],
   Dept2: ['jwillians', 'tessk'],
   //etc
]

def deptCf = ComponentAccessor.customFieldManager.getCustomFieldObjectsByName('Dept')[0]
def approverCf = ComponentAccessor.customFieldManager.getCustomFieldObjectsByName('Internal Approver')[0]
def approverName = issue.getCustomFieldValue(approverCf)?.name as String
def deptValue = issue.getCustomFieldValue(deptCf)?.value as String

//add some code here is you need to do something if either dept or approver fields are empty
//For example
if (!deptValue) {
   throw new InvalidInputException(deptCf.id, 'You must select the Department')
}
if (!approverName) {
   throw new InvalidInputException(approverCf.id, 'You must select the approver')
}

def validApprovers = departmentApproverMap[deptValue] as List<String>
if(!validApprovers){
   log.warn "The script does not contain approval mapping for deparment: $deptValue"
   return
}
if (!validApprovers.contains(approverName)) {
   def approverUserFullNames = validApprovers.findResults {userName->
      def user = ComponentAccessor.userManager.getUserByName(userName)
      if(!user){
         log.warn "The script contains an invalid username: $userName"
         return null
      }
      return user.displayName
   }
   throw new InvalidInputException(deptCf.id, "You selected a user that is not in the approved list: ${approverUserFullNames.join(', ')}")
}

Accepted answers

PD Sheehan

For single select fields, cfValues['Dept'] will give you an instance of an Option object.

To caompare it to a it to a string, you have to look a the getValue method.

Simliar thing for the userPicker. Those will be instanced of ApplicationUser.

If you are not sure, you can output the getClass() to the log then lookup in the details.

Try something like this

def approverName = cfValues['Internal Approver'].name
def deptValue = cfValues['Dept'].value == 'Dept1' 
deptValue == 'Dept1' && approverName in ['bobSm', 'micmal, 'TestUser1']

All comments

PD Sheehan

For single select fields, cfValues['Dept'] will give you an instance of an Option object.

To caompare it to a it to a string, you have to look a the getValue method.

Simliar thing for the userPicker. Those will be instanced of ApplicationUser.

If you are not sure, you can output the getClass() to the log then lookup in the details.

Try something like this

def approverName = cfValues['Internal Approver'].name
def deptValue = cfValues['Dept'].value == 'Dept1' 
deptValue == 'Dept1' && approverName in ['bobSm', 'micmal, 'TestUser1']

Sayed Bares [ServiceRocket]

@Michael

When querying single select list you will need to access its value property and if you are checking the username of the single user picker field then you need to query the username property. Additionally, the logic should be an OR operator instead of an AND if you want to pass validator for other departments (dept2, dept3 ...). Can you try this code and see if it works?

cfValues['Dept']?.value != 'Dept1' || cfValues['Internal Approver']?.getUsername() in ['Bob Smith', 'Michael M', 'Test_User']

If you only want to pass the validator if the dept1 is selected and its usernames then use an AND operator:

cfValues['Dept']?.value == 'Dept1' && cfValues['Internal Approver']?.getUsername() in ['Bob Smith', 'Michael M', 'Test_User']

The above query will fail the validator if other Depts are selected or other Internal Approvers are selected

Michael_qy22gs

Hello @PD Sheehan

For some reason this did not work. I've made sure to add the additional ' behind the micmal user name, but for some reason the validation always seems to come up false.

I've looked at the workflow log, and all relating values within the needed fields are correct with the exception of the Internal Approver name. The value within that field has both the username as well as their ID within it. Example: "micmal (JIRAUSER12345)".

Could this by why it's failing?

Thanks,

Mike

PD Sheehan

I think I missed that it was a multi-select.

In which case the value is an array of options.

To know the exact class returned, you need to manually output something to the log

e.g.

log.info "The value of 'Dept' is of type: ${cfValues[Dept].getClass()}"

I think this should work

def approverName = cfValues['Internal Approver'].name
def deptValues = cfValues['Dept'].value

'Dept1' in deptValues && approverName in ['bobSm', 'micmal', 'TestUser1']

Michael_qy22gs

Hello @Sayed Bares [ServiceRocket] ,

I should have originally stated that I want to setup this validator up for several different groups of people / departments; seeing as how I'm assuming that changes a lot about the script.

If I want to setup specific people per Department; for example:
Dept 1 = Bob Smith, Michael M, Test_User

Dept 2 = James Williams, Tess K

Dept 3 = Matt Smith, Joe Moe

How would I go about doing this?

Thanks,

Mike

Michael_qy22gs

Hi again @PD Sheehan

The "Dept" field is a single select. and the Internal Approver field is "single select user picker".

I should have stated up above, but I'm also looking to have specific users be the only "valid" choice for specific departments selected within the "Dept" single select drop down field.

Example:

Dept 1 = Bob Smith, Michael M, Test_User

Dept 2 = James Williams, Tess K

Dept 3 = Matt Smith, Joe Moe

I would assume that this would change the requirements of my scripting quite a bit correct?

Thanks,

Mike

Sayed Bares [ServiceRocket]

@Michael just add an OR operation or use @PD Sheehan suggestion either way should work

(cfValues['Dept']?.value == 'Dept1' && cfValues['Internal Approver']?.getUsername() in ['Bob Smith', 'Michael M', 'Test_User']) || (cfValues['Dept']?.value == 'Dept2' && cfValues['Internal Approver']?.getUsername() in ['James Williams', 'Tess K']) || (cfValues['Dept']?.value == 'Dept3' && cfValues['Internal Approver']?.getUsername() in ['Matt Smith', 'Joe Moe'])

Welcome!

It looks like you're new here. Sign in or register to get started.

Quick Links

Find more posts tagged with

server

scriptrunner

adaptavist