ScriptRunner Behaviours: change select list based on customfield value

bSte

Hello - I am trying to show different select list options depending on the custom field value selected.  My script is not working, below is the script I am using.  

 

import com.atlassian.jira.component.ComponentAccessor

def optionsManager = ComponentAccessor.getOptionsManager()
def customFieldManager = ComponentAccessor.getCustomFieldManager()

def vertical = getFieldById("customField_10433")
def verticalValue = vertical.getValue()

if (vertical == "Retail"){
def retailOptions = optionsManager.getOptions(fieldConfig){
it.name in ["Email", "Audience Workshop", "Audience Plan", "Media Plan", "RFP", "Proactive Audience Outreach", "Campaign Tracker"]
}
else {
def autoOptions = optionsManager.getOptions(fieldConfig){
it.name in ["chevy", "ford", "buick"]
}
getFieldbyId("customfield_12711").setFieldOptions(allowedOptions)
}
}

JohnsonHoward

Hi Ashlee,

There are a few reasons why this script is not working:

1. Your curly braces are misplaced ( these ones -> {} ).

2. You haven't got the field config for the options, so your 'fieldConfig' value that you have passsed to getOptions() will be null.

3. You need to add .FindAll() between your closure and getOptions(method), as you are currently checking for a boolean. 

4. You have not assigned anything to the 'allowedOptions' value you are passing to .setFieldOptions() method.

Other tips are:

1. Get the field by name instead of ID, as this accounts for system migrations

2. toString() the vertical value in the if statement so that you are always comparing two of the same object types

The script below has corrected all the issues. It is untested but I believe it should work. Let me know if you have more issues.

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.issue.Issue
import com.onresolve.jira.groovy.user.FieldBehaviours
import groovy.transform.BaseScript
@BaseScript FieldBehaviours fieldBehaviours
Issue issue = issue
def optionsManager = ComponentAccessor.getOptionsManager()
def customFieldManager = ComponentAccessor.getCustomFieldManager()
def vertical = getFieldByName("vertical")
def otherField = getFieldByName("other field")
def otherFieldCustomField = customFieldManager.getCustomFieldObjectByName("other field")
def verticalValue = vertical.getValue()
def fieldConfig = otherFieldCustomField.getRelevantConfig(issue)
def allowedOptions = null

if (verticalValue.toString() == "Retail"){
   allowedOptions = optionsManager.getOptions(fieldConfig).findAll{
        it.value in ["Email", "Audience Workshop", "Audience Plan", "Media Plan", "RFP", "Proactive Audience Outreach", "Campaign Tracker"]
    }
}else {
    allowedOptions = optionsManager.getOptions(fieldConfig).findAll{
        it.value in ["chevy", "ford", "buick"]
    }

}
otherField.setFieldOptions(allowedOptions)

Thanks

Johnson Howard (Adaptavist)