Transition all linked Stories to an Epic

Linus Lindroth

Hi folks

I've been trying to find examples of code so I can transition all linked stories to an Epic if the Epic is moved to state "Approved" for example. I use Script Runner and there are plenty of examples the other way around, ie transition the Epic if all linked Stories are completed for example.

Can anyone guide me to how I add a post-function so moving the Epic to state "Approved" will move the Stories to a certain state? Assume the Stories are all in a certain state and I know what the next state is.

I would be very thankful.

Geert_Graat

Hi,

The script below is something I have made to transfer a related issue to a certain state once a bug is resolved. What it does:

• Check if there is a relation of a certain type to this issue (a lot of hardcoded stuff in here, because I create this relation with another script in workflow)
• Check if the related issue is in a certain state
• Transition the related issue to a predefined state
• Add a comment to the related issue

I think you just have to slightly modify this by looking up the appropriate IDs of your relation, status and workflow.

A tip on those IDs: when I was playing with this script, I was also configuring the Auto Transition Listener. When you edit the configuration of the listener, it displays a list of all workflows, statuses, events, including ID. Nice for lookup.

 

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.security.JiraAuthenticationContext
import com.atlassian.jira.workflow.WorkflowTransitionUtil;
import com.atlassian.jira.workflow.WorkflowTransitionUtilImpl;
import com.atlassian.jira.util.JiraUtils;
import com.atlassian.jira.issue.link.IssueLinkManager
import com.atlassian.jira.issue.comments.CommentManager
def compAccessor = new ComponentAccessor()
// retrieve the inward links for the issue (Support Request = source, Bug = destination)
def linkManager = compAccessor.getIssueLinkManager()
def links = linkManager.getInwardLinks(issue.getId())
for (link in links) {
    if (link.getIssueLinkType().getId() == 10500 as Long) {
    // since the issue was created by the relatedIssue, simply assume here that the first link is the correct one
        def relatedIssue = link.getSourceObject()
        // check that related issue status is To Dev, otherwise do nothing
        def status = relatedIssue.getStatusObject().getSimpleStatus().getId()
        if (status == "10019") {
            // get the user who resolved the bug
            def authContext = compAccessor.getJiraAuthenticationContext()
            def userKey = authContext.getUser().getKey()
             
            // create the workflow action to Dev Ready
            def workflowTransitionUtil = ( WorkflowTransitionUtil ) JiraUtils.loadComponent( WorkflowTransitionUtilImpl.class )
            workflowTransitionUtil.setIssue(relatedIssue)
            workflowTransitionUtil.setUserkey(userKey)
            workflowTransitionUtil.setAction(81)
         
            // add a comment so support sees what triggered the status change (only visible on Developer [10001] level)
            def commentManager = compAccessor.getCommentManager()
            String comment = "[auto-comment] Bug "+ issue.getKey() +" causing this support request has been resolved."
            commentManager.create(relatedIssue, userKey, comment, null, 10001 as Long, true)
             
            // validate and transition issue
            workflowTransitionUtil.validate()
            workflowTransitionUtil.progress()
        }
    }
}