How add user to a custom field based on value of other field?

Shah Baloch

Hi Community, there is an existing Behaviour script that I need to modify. The current script working fine. If the number is 10000 or less it add the user1 to a user field but if the number is greater than 10000 it add user2 to the user field. There is an additional requirement now. If the number is 5000 or less add reporter to user field, if number is more than 5000 and 1000 or less add user1 to user field greater than 10000 should be the same. Here is an example:
5000 or less = Issue Reporter
Greater than 5000 and less than 1000 = User1
Greater than 10000 = User2

How can modify and achieve the requirement?

import com.onresolve.jira.groovy.user.FieldBehaviours
import groovy.transform.BaseScript
@BaseScript FieldBehaviours fieldBehaviours

def userFormField = getFieldById('customfield_11305')
def textFormField = getFieldById('customfield_11306')

Integer number = textFormField.getValue() as Integer
String user = number > 10000 ? 'user2' : 'user1'
userFormField.setFormValue(user)

Thank you,

PD Sheehan

There are many ways to achieve that.

One way is to use the existing construct and just expand it:

import com.atlassian.jira.issue.IssueFieldConstants
import com.onresolve.jira.groovy.user.FieldBehaviours
import groovy.transform.BaseScript
@BaseScript FieldBehaviours fieldBehaviours

def userFormField = getFieldById('customfield_11305')
def textFormField = getFieldById('customfield_11306')
def reporterField  = getFieldById(IssueFieldConstants.REPORTER)
Integer number = textFormField.getValue() as Integer
String user = number > 10000 ? 'user2' : number > 5000 ? 'user1' : reporterField.value
userFormField.setFormValue(user)

But that might be hard to read.

Another way can be a bit more explicit:

import com.atlassian.jira.issue.IssueFieldConstants
import com.onresolve.jira.groovy.user.FieldBehaviours
import groovy.transform.BaseScript

@BaseScript FieldBehaviours fieldBehaviours

def userFormField = getFieldById('customfield_11305')
def textFormField = getFieldById('customfield_11306')
Integer number = textFormField.getValue() as Integer
String user
if (number > 10000) {
    user = 'user2'
} else if (number <= 10000 && number > 5000) {
    user = 'user1'
} else {
def reporterField = getFieldById(IssueFieldConstants.REPORTER)
    user = reporterField.value
}
userFormField.setFormValue(user)

This assumes the reporter field is available to the behaviour (present on the screen).

If it is not and what you really want is the currently logged-in user, then you can try it like this

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.issue.IssueFieldConstants
import com.onresolve.jira.groovy.user.FieldBehaviours
import groovy.transform.BaseScript

@BaseScript FieldBehaviours fieldBehaviours

def userFormField = getFieldById('customfield_11305')
def textFormField = getFieldById('customfield_11306')
Integer number = textFormField.getValue() as Integer
String user
if (number > 10000) {
    user = 'user2'
} else if (number <= 10000 && number > 5000) {
    user = 'user1'
} else {
def currentUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser
    user = currentUser.name
}
userFormField.setFormValue(user)