Keeping custom field in Sub-Task consistent and updated with field in parent

Rok Antolic

Hello,

I would like the field "Verteilung" in Sub-Task to always be up to date, because the same field in parent tends to change from time to time and we need them synced. All that would be easy with scripted field but the field is actually type Select List (single choice) for which there is no custom template, at least I didn't find anything on it so far on google. Is this possible at all?

Cheers,

Rok

Jeremy Gaudet

I've actually tried this with a scripted field, and it's messy because you then have to search using two different fields, the source field for the parent, and the separate scripted field for the child.  Syncing can be accomplished using a script listener that looks for changes to the parent that include the field and then updates the children.  Here is code I use to sync two fields, a custom field called "Verified Version/s" and the normal "Fix Version/s" field.  The listener is on all events that could change the field... Issue Updated, Issue Resolved, etc.

package com.myorg.listeners


import org.apache.log4j.Category
import com.atlassian.jira.ComponentManager
import com.atlassian.jira.event.issue.AbstractIssueEventListener
import com.atlassian.jira.event.issue.IssueEvent
import com.atlassian.jira.issue.Issue
import com.atlassian.jira.project.version.Version
import com.atlassian.jira.config.SubTaskManager
import com.atlassian.jira.issue.IssueManager
import com.atlassian.jira.issue.CustomFieldManager
import com.atlassian.jira.issue.fields.CustomField
import com.atlassian.jira.event.type.EventDispatchOption
import java.util.ArrayList
import java.util.Collection

class SyncParentFixVerifiedVersionsToSubTask extends AbstractIssueEventListener 
{
	Category log = Category.getInstance(SyncParentFixVerifiedVersionsToSubTask.class);
	SubTaskManager subTaskManager = ComponentManager.getInstance().getSubTaskManager();
	IssueManager issueManager = ComponentManager.getInstance().getIssueManager();
	CustomFieldManager customFieldManager = ComponentManager.getInstance().getCustomFieldManager();

	Boolean changed = false;

	@Override
	void workflowEvent(IssueEvent event) {
		try {
			if (subTaskManager.isSubTasksEnabled()) {
				Issue eventIssue = event.getIssue();
				Collection<Issue> subTasks = eventIssue.getSubTaskObjects();
				if ( !eventIssue.getIssueTypeObject().isSubTask() ) {
					List changeItems = event.getChangeLog().getRelated("ChildChangeItem");
					if( changeItems.any {it.get('field')=='Fix Version'} ) {
						changed = true;
						Collection<Version> fixVersions = new ArrayList<Version>();
						fixVersions = eventIssue.getFixVersions();
						if (!subTasks.isEmpty()) {
							subTasks.each {
								it.setFixVersions(fixVersions);
							}                     
						}
					}
					if( changeItems.any {it.get('field')=='Verified Version/s'} ) {
						changed = true;
						CustomField vvcf = customFieldManager.getCustomFieldObjectByName("Verified Version/s");
						Collection<Version> verifiedVersions = new ArrayList<Version>();
						verifiedVersions = eventIssue.getCustomFieldValue(vvcf);
						if (!subTasks.isEmpty()) {
							subTasks.each {
								it.setCustomFieldValue(vvcf,verifiedVersions);
							}
						}
					}
					if (changed) {
						subTasks.each {
							issueManager.updateIssue(event.getUser(), it, EventDispatchOption.ISSUE_UPDATED, false);
						}
					}
				}
			}
		}
		catch (ex) {
			log.debug "Event: ${event.getEventTypeId()} fired for ${event.issue} and caught by SyncParentFixVerifiedVersionsToSubTask"
			log.debug (ex.getMessage())
		}
	}
}