How do I get current Customer Request Type in Behaviours?

Szymon Trocha_65s9jd

Hi all,

I'm trying to build an Initializer script in Behaviours. I have one behaviour for different Customer Reuqest Types. What I want to get is that when issue is created (both by an agent and from user portal) depending on the Customer Request Type some fields are hidden in the initiallly loaded Create issue window.

I'm having troubles in fetching the current value of Customer Reuqest Type field for both the agent and when user creates via portal. So far I have the current code based on a mixture of some found code:

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.servicedesk.api.requesttype.RequestTypeService
import com.onresolve.scriptrunner.runner.customisers.PluginModule
import com.onresolve.scriptrunner.runner.customisers.WithPlugin

@WithPlugin("com.atlassian.servicedesk")
@PluginModule
RequestTypeService requestTypeService

def issue = event.issue
def currentUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser
def customFieldManager = ComponentAccessor.customFieldManager
def requestTypeCustomField = customFieldManager.getCustomFieldObjects(issue).findByName('Customer Request Type')
log.warn("log-behaviour-hide-fields-colocation INITIALIZE customField value: " + customField)

but I'm stucked at this stage. The Scriptrunner checker print error "[Static type checking] - Cannot find matching method com.atlassian.jira.issue.CustomFieldManager#getCustomFieldObjects(java.lang.Object). Please check if the declared type is correct and if the method exists." so even doesn't allow me to proceed further.

Hod do I properly retrieve the current value of Customer Request Type when creating an issue?

I'm using Jira Software 8.22.4, Jira Service Management 4.22.4 and ScriptRunner v. 6.53

Thank you in advance

PD Sheehan

Hi @Szymon Trocha  I have 4 observations about your question.

First, "Static Type Checking Errors" do not necessarily show stoppers.

Groovy by design can be dynamically typed or strongly typed. The downside of relying on dynamic typing is the occasional inability of some parsers to detect the correct type inference to validate the syntax.
In many cases, the code will run just fine. 

Second, I see "event.issue" in your script... so this looks like you copied it from a Scripted Event Listener. That won't work out of the box for a behaviour. Also, in a behaviour, especially one triggered during issue creation, there will be no issue object available. So issue.getCustomFieldValue(customField) will not be an option. You need to use behaviour methods.

Third, when a behaviour is called from the portal, you will have access to "getRequestTypeName()" as a built-in method in your script. You should use that if it's available as the first option. Only fall back to the more complex code if you absolutely have to.

Fourth, the value for the Customer Request Type will yield a "key" that looks like "abc/c18c3b9c-aceb-4c8b-9e9c-d40c9c17ee02". Not terribly useful for performing some logic. I see you were on the right track with requestTypeService.

Putting all that together, I propose this:

import com.atlassian.servicedesk.api.ServiceDeskManager
import com.atlassian.servicedesk.api.requesttype.RequestTypeService
import com.onresolve.jira.groovy.user.FieldBehaviours
import com.onresolve.scriptrunner.runner.customisers.PluginModule
import com.onresolve.scriptrunner.runner.customisers.WithPlugin
import groovy.transform.BaseScript

@WithPlugin("com.atlassian.servicedesk") //allows you to import com.atlassin.servicedesk
@BaseScript FieldBehaviours fieldBehaviours //not needed if you store your script in-line, but helpful when using in script editor or in an external IDE
@PluginModule RequestTypeService requestTypeService 
@PluginModule ServiceDeskManager serviceDeskManager

def requestTypeName = getRequestTypeName()
if (!requestTypeName) {
def custerRequestTypeFormField = getFieldByName('Customer Request Type')
    String requestTypeKey = custerRequestTypeFormField.value
    if (!requestTypeKey) {
log.error "No customer request type has been detected. This behaviour can't function"
        return
    }
def sd = serviceDeskManager.getServiceDeskForProject(issueContext.projectObject)
def queryBuilder = requestTypeService.newQueryBuilder()
    queryBuilder.requestOverrideSecurity(true)
    queryBuilder.serviceDesk(sd.id)
def allRequestTypes = requestTypeService.getRequestTypes(null, queryBuilder.build()).results
    def requestType = allRequestTypes.find {
        log.debug "$it.properties.key (${requestTypeKey.contains(it.properties.key as String)})"
        requestTypeKey.contains(it.properties.key as String)
}
    if (!requestType) {
log.error "No Request Type matching the key present in Customer Request Type ($requestTypeKey) can be found in $issueContext.projectObject.key. This behaviour can't function"
        return
    }
    requestTypeName = requestType.name
}

def requestTypeFieldsToHide = [
"requestTYpe1": ['fieldA', 'fieldb', 'fieldc'],
"requestTYpe2": ['fieldC', 'fieldD', 'fieldE']
]

requestTypeFieldsToHide[requestTypeName].each { fieldName ->
    getFieldByName(fieldName).setHidden(true)
}