How to use ContentService instead of PageManager?

ABoerio

Hi, 

in my SR scripts I often use PageManager methods (especially getPage()) to get information about pages.

As by https://docs.atlassian.com/ConfluenceServer/javadoc/7.9.1/  I noticed that getPage() is deprecated, and ContentService.find() is recommended.

Sorry to admit that I've never used yet succesfully ContentService to get done what I need, due to my knowledge lack.

Looking at the following simple code, which obviously runs with no problems in my instance:

import com.atlassian.sal.api.component.ComponentLocator
import com.atlassian.confluence.pages.PageManager
import com.atlassian.confluence.pages.Page

def myKnownPageTitle='Title of my page'
def mySpaceString='Name of my space'

def pageManager = ComponentLocator.getComponent(PageManager)
def myPage = pageManager.getPage(mySpaceString, myKnownPageTitle)
def myRetrievedId = myPage.getId()
def myRetrievedPageVersion=myPage.getVersion()

log.warn("Page searched: ${myKnownPageTitle}")
log.warn("Retrieved page ID is: ${myRetrievedId}")
log.warn("Current page version is: ${myRetrievedPageVersion}")

How should I implement ContentService to get the same result?

I have no problem in living with deprecated methods (until they run :-)) but of course I'd like to progressively improve.

Thanks in advance for any hint.

Ciao, Andrea

 

 

Tiffany Wortham

Here's the updated script from the Champion Hour!

import com.atlassian.confluence.api.model.Expansion
import com.atlassian.confluence.api.model.content.ContentType
import com.atlassian.confluence.api.service.content.ContentService
import com.atlassian.confluence.api.service.content.SpaceService
import com.onresolve.scriptrunner.runner.ScriptRunnerImpl

def contentService = ScriptRunnerImpl.getPluginComponent(ContentService)
def spaceService = ScriptRunnerImpl.getPluginComponent(SpaceService)

def title ='Welcome To Confluence'

def space = spaceService.find(new Expansion('name'))
    .withKeys('ds')
    .fetch()
    .get()

def findMatchingPage = contentService.find(new Expansion('version'), new Expansion('id'))
    .withType(ContentType.PAGE)
    .withSpace(space)
    .withTitle(title)
    .fetch()

def page = findMatchingPage.get()
def pageId = page.id
def pageVersion = page.version

log.debug("Page searched: ${title}")
log.debug("Retrieved page ID is: ${pageId}")
log.debug("Current page version is: ${pageVersion}")