Is there a way to bulk edit users in JIRA?

Susan Hazlett2

I am migrating from Bugzilla to JIRA and while the Bugzilla users come into the system under a group called "bugzilla-import-disabled-users" or "bugzilla-import-unused-users", they are coming in as "active". This is triggering an error for licensing, and with > 2000 disabled/unused users, I don't want to have to edit these all manually. Can anyone point me to how I can do this in bulk?

Thanks!

Henning Tietgens

You can use the Script Runner plugin and the following script:

import com.atlassian.crowd.embedded.api.CrowdService
import com.atlassian.crowd.embedded.api.User
import com.atlassian.crowd.embedded.api.UserWithAttributes
import com.atlassian.crowd.embedded.impl.ImmutableUser
import com.atlassian.jira.bc.user.UserService
import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.user.util.UserUtil

String result = ''

UserUtil userUtil = ComponentAccessor.userUtil
CrowdService crowdService = ComponentAccessor.crowdService
UserService userService = ComponentAccessor.getComponent(UserService.class)
User updateUser
UserWithAttributes user
UserService.UpdateUserValidationResult updateUserValidationResult

def groupNames = [
        'bugzilla-import-disabled-users',
        'bugzilla-import-unused-users'
]

userUtil.getAllUsersInGroupNamesUnsorted(groupNames).findAll{it.isActive()}.each { 
    user = crowdService.getUserWithAttributes(it.getName())
    updateUser = ImmutableUser.newUser(user).active(false).toUser()
    updateUserValidationResult = userService.validateUpdateUser(updateUser)
    if (updateUserValidationResult.isValid()) {
        userService.updateUser(updateUserValidationResult)
        result += "Deactivated ${updateUser.name}"
    } else {
        result += "Update of ${user.name} failed: ${updateUserValidationResult.getErrorCollection().getErrors().entrySet().join(',')}"
    }
}
return result

Please test in testsystem first!

Henning