How to create projects in post-function with API from Scriptrunner built-in function "copy project"?

Johannes Heger (CD)

Currently the Jira admin (me) creates new projects from a template project with Scriptrunner built-in function "copy project".

I like to give collegues the ability to create projects as well, but in a post-function. These collegues don't have Jira admin privelliges.

The project name and the project key will be in custom fields. The template project key should be configured in the post-function. The post-function has to run with Jira admin privileges.

Is there any grovvy script out there to accomplish this?

Best regards, Johannes

PD Sheehan

You can call the built-in script from a post function custom script. But you should validate it first in a validator custom script in case any of the input fail.

So something like this in validator:

import com.onresolve.scriptrunner.canned.jira.admin.CopyProject
import com.opensymphony.workflow.InvalidInputException

def sourceKey = ''
def targetKey = ''
def targetName = ''

def copyProject = new CopyProject()
def inputs = [
    (CopyProject.FIELD_SOURCE_PROJECT)       : sourceKey,
    (CopyProject.FIELD_TARGET_PROJECT)       : targetKey,
    (CopyProject.FIELD_TARGET_PROJECT_NAME)  : targetName,
    (CopyProject.FIELD_COPY_VERSIONS)        : false,
    (CopyProject.FIELD_COPY_COMPONENTS)      : false,
    (CopyProject.FIELD_COPY_ISSUES)          : false,
    (CopyProject.FIELD_COPY_DASH_AND_FILTERS): false
]

def errorCollection = copyProject.doValidate(inputs, false)
if (errorCollection.hasAnyErrors()) {
    log.warn("CopyProject input invalid: $errorCollection")
    throw new InvalidInputException(errorCollection)
}

And this in the post function

import com.onresolve.scriptrunner.canned.jira.admin.CopyProject
import com.onresolve.scriptrunner.runner.util.UserMessageUtil
import com.atlassian.jira.component.ComponentAccessor

def adminUser = 'admin'
def sourceKey = ''
def targetKey = ''
def targetName = ''

def copyProject = new CopyProject()
def inputs = [
    (CopyProject.FIELD_SOURCE_PROJECT) : sourceKey,
    (CopyProject.FIELD_TARGET_PROJECT) : targetKey,
    (CopyProject.FIELD_TARGET_PROJECT_NAME) : targetName,
    (CopyProject.FIELD_COPY_VERSIONS) : false,
    (CopyProject.FIELD_COPY_COMPONENTS) : false,
    (CopyProject.FIELD_COPY_ISSUES) : false,
    (CopyProject.FIELD_COPY_DASH_AND_FILTERS): false
]


ComponentAccessor.getJiraAuthenticationContext().setLoggedInUser(ComponentAccessor.userManager.getUserByName(adminUser))
def cpOutput = copyProject.doScript(inputs)
def newProject = ComponentAccessor.projectManager.getProjectObjByKeyIgnoreCase(targetKey)
if (!newProject) {
   UserMessageUtil.error("There was an error creating your project. Contact your Jira Admin")
} else {
   UserMessageUtil.success("$targetKey project created successfully")
}

 You'll have to either hard code or fetch from custom fields the values for sourceKey, targetKey  and targetName. Also, you may want to set other copy options for version, components etc.