Restrict Priority by Role and Custom Field using ScriptRunner Behaviours

Neil_7kmg2n

Hi everyone.

This is my first post (likely not my last), I've tried searching through other questions and other sites for my answer however I am struggling to get to where I need - I get close but not close enough!

I am running Jira 7.11.0 Server and ScriptRunner 5.5.5

On all issues I have a checkbox that when checked I want to prevent users who are not in a specific Project Role from selecting a specific priority level.

I have seen the example script here however this does not do exactly what I want, I have no experience in Java/Groovy so do not know what I need to do in order to modify this to suit my needs.

My custom field id for my checkbox is 'customfield_23347', it is currently restricted so that it is only able to be edited by users in the 'Administrators' Project Role.

Minimum Requirement:

• When 'customfield_23347' is checked, if the user is not in a Role of a Project Administrator, then the list of available priorities should be restricted (e.g. the option to select Critical should not be available).
• If 'customfield_23347' is not checked then there should be no restrictions and users should see all available priority levels.

Nice to have:

• When the above restriction is in place, advise the user with a comment under the Priority field that they are unable to set a specific priority level since they are not an Administrator of the project.

There is no concern around users setting the priority and then checking the checkbox since only Administrator are able to set this checkbox and will be responsible for ensuring that the priority level is set correctly.

Thank you in advance for your help!

PD Sheehan

Part of the trick here is that with Jira 7 ... a new Priority Scheme has been added to projects and just filtering from the list of all priorities obtained from constantsManaeger.getPrioririties() will return more values than are in your project.

Also, since you are interested in project role rather than jira admin , we need a different component (rather than userUtil).

Putting all that together with some flexible logic in case you need to change the list of restricted priorities or roles, a script like the following should work.

import com.atlassian.jira.component.ComponentAccessor
import static com.atlassian.jira.issue.IssueFieldConstants.PRIORITY
import com.atlassian.jira.security.roles.ProjectRoleManager
import com.atlassian.jira.issue.fields.config.manager.PrioritySchemeManager

def projectRoleManager = ComponentAccessor.getComponent(ProjectRoleManager)
def prioritySchemeManager = ComponentAccessor.getComponent(PrioritySchemeManager)

def currentUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser
def priorityFld = getFieldById(PRIORITY)

def restrictedPriorities = ['Critical', 'more if needed']
def permittedProjectRoles = ['Administrators', 'Some Other Role']

//gett role objects for the roles that are permitted to access restricted priorities
def projectRoles = projectRoleManager.projectRoles.findAll{it.name in permittedProjectRoles }


//examine each permitted roles to see if the user belongs, if they don't belong to any ... they'll be restricted
if (!projectRoles.any{projectRoleManager.isUserInProjectRole(currentUser, it, issueContext.getProjectObject() )}){
   //get a collection of priorities objects relevant for the current issue context 
   def contextPriorities = prioritySchemeManager.getPrioritiesFromIds(prioritySchemeManager.getOptions(issueContext))
   //filter to remove restrictedPriorities and construct a map object
   def allowedPriorities = contextPriorities .findAll{
      !(it.name in restrictedPriorities)
   }.collectEntries {
      [(it.id): it.name]
   }

   //apply the map object to the priority field (this overwrites the default list)
   priorityFld.setFieldOptions(allowedPriorities)

   //provide some contextual help to the user
   priorityFld.setHelpText("Access to some priorities have been disabled: $restrictedPriorities.<br>Contact a member of $permittedProjectRoles if this priority needs to be assigned.")

}