Scriptrunner Update Issues in Epic custom field

Raynard Rhodes_y6vawn

I'm new to using scriptrunner and scripting in general. I've been attempting to copy the value of an Epic's custom field to all of the Issues in Epic custom field of the same name. I've attempted this and am looking for guidance.

**Updated Code. No errors show, but linked issues custom fields are not being updated**

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.issue.link.IssueLink
import com.atlassian.jira.issue.CustomFieldManager
import com.atlassian.jira.issue.Issue
import com.atlassian.jira.issue.link.IssueLinkManager
import com.atlassian.jira.issue.IssueManager
import com.atlassian.jira.event.issue.IssueEvent
import com.atlassian.jira.issue.util.DefaultIssueChangeHolder
import com.atlassian.jira.issue.ModifiedValue





def linkType = "Issue in Epic"


def linkMgr = ComponentAccessor.getIssueLinkManager()
def cfManager = ComponentAccessor.getCustomFieldManager()
def issueManager = ComponentAccessor.getIssueManager()

def event = event as IssueEvent
Issue issue = event.issue as Issue


def accountField = cfManager.getCustomFieldObjects(issue)?.find{it.name == "Account"}
def cfValue = issue.getCustomFieldValue(accountField)
def epicLink = cfManager.getCustomFieldObjectByName("Epic Link")
def epicName = cfManager.getCustomFieldObjectByName("Epic Name")


def change = event?.changeLog?.getRelated("ChildChangeItem")?.find{it.field == accountField}

if (!change){
return
}


def linkedIssue = ComponentAccessor.issueLinkManager.getOutwardLinks(issue.id).findAll{it.issueLinkType.name == linkType}

if (!linkedIssue){
return
}

if (change){
linkedIssue.each{
def linkedIssueObj = it.destinationObject
def oldValue = linkedIssueObj.getCustomFieldValue(accountField)
def newValue = issue.getCustomFieldValue(accountField) 

accountField.updateValue(null, linkedIssueObj, new ModifiedValue(oldValue, newValue), new DefaultIssueChangeHolder())

}
}

PD Sheehan

You are missing a line to actually change the value on the issue.

linkedIssueObj.setCustomFieldValue(accountField, issue.getCustomFieldValue(accountField) )

But note that this will not cause your linkedIssue to show the history of that change. You will need to add that yourself if you care.

Alternatively, use issueManager.updateIssue() instead

Also, the linkedIssue will not be re-indexed so it will still come up when you search for the old value.

So your full script could look like this:

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.issue.Issue
import com.atlassian.jira.event.issue.IssueEvent
import com.atlassian.jira.util.ImportUtils
import com.atlassian.jira.issue.index.IssueIndexingService
import com.atlassian.jira.event.type.EventDispatchOption

def linkType = "Issue in Epic"


def linkMgr = ComponentAccessor.issueLinkManager
def cfManager = ComponentAccessor.customFieldManager
def issueManager = ComponentAccessor.issueManager
def issueIndexingService = ComponentAccessor.getComponent(IssueIndexingService.class)

def event = event as IssueEvent
Issue issue = event.issue as Issue
def currentUser = ComponentAccessor.jiraAuthenticationContext.loggedInUser

def accountField = cfManager.getCustomFieldObjects(issue)?.find{it.name == "Account"}
def cfValue = issue.getCustomFieldValue(accountField)
def epicLink = cfManager.getCustomFieldObjectByName("Epic Link")
def epicName = cfManager.getCustomFieldObjectByName("Epic Name")

def change = event?.changeLog?.getRelated("ChildChangeItem")?.find{it.field == accountField}

if (!change){
   return
}

def linkedIssue = linkMgr.getOutwardLinks(issue.id).findAll{it.issueLinkType.name == linkType}

if (!linkedIssue){
   return
}

if (change){
   linkedIssue.each{
      def linkedIssueObj = it.destinationObject
      linkedIssueObj.setCustomFieldValue(accountField, cfValue) 

      issueManager.updateIssue(currentUser, linkedIssueObj , EventDispatchOption.DO_NOT_DISPATCH, false)

      def wasIndexing = ImportUtils.isIndexIssues()
      ImportUtils.setIndexIssues(true)
      issueIndexingService.reIndex(linkedIssueObj)
      ImportUtils.setIndexIssues(wasIndexing)
   }
}