How to change the background color of a HTML customField in Scriptrunner to the "Epic Color"?

C_S_

I have used a code I found to create a scripted custom field with scriptrunner that shows me the Epic Link in a issue and also a Sub-Task.

I now want the custom field to have the epic color as the background color, because we use the color to identify different categories of topics (to save a column on the dashboard we use for stand up meetings).

Currently the output of the field is:

Epic Name

I want:

 

The code I used is:

import com.atlassian.jira.component.ComponentAccessor;
import com.atlassian.jira.issue.CustomFieldManager;
import com.atlassian.jira.issue.fields.CustomField;
import com.atlassian.jira.issue.Issue;
CustomFieldManager cfManager = ComponentAccessor.getCustomFieldManager();
CustomField epicLink = cfManager.getCustomFieldObjectByName('Epic Link');
CustomField epicName = cfManager.getCustomFieldObjectByName('Epic Name');
//This is where we store the issue that is linked to the epic.
Issue issue_linked_to_epic
/* determine if this is an epic, if so, return the epic link name */
if (issue.issueTypeObject.name == "Epic"){
return issue.getCustomFieldValue(epicName)
}
/*determine if this is a subTaskIssueTypes(), if so, set the parent to the issue linked to the epic */
Issue issueParent = issue.getParentObject()
if (issueParent == null){
issue_linked_to_epic = issue
} else {
issue_linked_to_epic = issueParent
}
/* get epic link */
Issue epic = (Issue) issue_linked_to_epic.getCustomFieldValue(epicLink)
if (epic == null){
return null
}
String epicNameString = epic.getCustomFieldValue(epicName)
return '<a href=myURL'+ epic +'>'+ epicNameString +'</a>'

 

 

Thank you a lot!

PD Sheehan

At first, I was going to say you can't do that ... but with a bit of perseverance ... I think  I found something that might work for you:

Try this:

import com.atlassian.jira.component.ComponentAccessor;
import com.atlassian.jira.issue.CustomFieldManager;
import com.atlassian.jira.issue.fields.CustomField;
import com.atlassian.jira.issue.Issue;

CustomFieldManager cfManager = ComponentAccessor.getCustomFieldManager();
CustomField epicLink = cfManager.getCustomFieldObjectByName('Epic Link');
CustomField epicName = cfManager.getCustomFieldObjectByName('Epic Name');
CustomField epicColor = cfManager.getCustomFieldObjectByName('Epic Colour');
//This is where we store the issue that is linked to the epic.
Issue issue_linked_to_epic
/* determine if this is an epic, if so, return the epic link name */
if (issue.issueType.name == "Epic"){
   return issue.getCustomFieldValue(epicName)
}
/*determine if this is a subTaskIssueTypes(), if so, set the parent to the issue linked to the epic */
Issue issueParent = issue.getParentObject()
if (issueParent == null){
   issue_linked_to_epic = issue
} else {
   issue_linked_to_epic = issueParent
}
/* get epic link */
Issue epic = (Issue) issue_linked_to_epic.getCustomFieldValue(epicLink)
if (epic == null){
   return null
}
String epicNameString = epic.getCustomFieldValue(epicName)
String epicColorVal = epic.getCustomFieldValue(epicColor)


return """<a class="aui-label $epicColorVal" href="/browse/$epic">$epicNameString</a>"""

Changed or added lines are bold & underlined 

Note, you don't need to put your full url... just start with "/browse" and that will start at the root of your site. You may need to include /jira/browse if you have multiple apps/instances on the same server. Also using triple quoted lines for HTML makes things much easier to manage and read than to use single quotes and +